CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11)
   2
   3 project(ceph)
   4 set(VERSION 12.2.8)
   5
   6 if(POLICY CMP0046)
   7   # Tweak policies (this one disables "missing" dependency warning)
   8   cmake_policy(SET CMP0046 OLD)
   9 endif()
  10 # we use LINK_PRIVATE keyword instead of PRIVATE, but do not specify the LINK_PUBLIC
  11 # for target_link_libraries() command when PUBLIC should be used instead, it's just
  12 # for backward compatibility with cmake 2.8.11.
  13 if (POLICY CMP0022)
  14 cmake_policy(SET CMP0022 OLD)
  15 endif (POLICY CMP0022)
  16 if (POLICY CMP0023)
  17 cmake_policy(SET CMP0023 OLD)
  18 endif (POLICY CMP0023)
  19 if(POLICY CMP0056)
  20   cmake_policy(SET CMP0056 NEW)
  21 endif()
  22 if(POLICY CMP0065)
  23   cmake_policy(SET CMP0065 NEW)
  24 endif()
  25 if(POLICY CMP0051)
  26   # cmake 3.1 and higher include generator expressions in SOURCES property.
  27   # in BuildBoost.cmake, get_target_property(<var> <target> SOURCES) is used
  28   # to retrieve the source files of a target. in that case, we are only
  29   # interested in the *source* files. and i don't want to bother stripping off
  30   # the TARGET_OBJECTS elements from the returned SOURCES. so let's stick with
  31   # the old behavior now.
  32   cmake_policy(SET CMP0051 OLD)
  33 endif()
  34 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules/")
  35
  36 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  37   set(LINUX ON)
  38   FIND_PACKAGE(Threads)
  39 elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  40   set(FREEBSD ON)
  41   FIND_PACKAGE(Threads)
  42 elseif(APPLE)
  43   set(OperatingSystem "Mac OS X")
  44 else()
  45   message(STATUS "No systemtype selected for building")
  46 endif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  47
  48 option(WITH_CCACHE "Build with ccache.")
  49 if(WITH_CCACHE)
  50   find_program(CCACHE_FOUND ccache)
  51   if(CCACHE_FOUND)
  52     message(STATUS "Building with ccache: ${CCACHE_FOUND}, CCACHE_DIR=$ENV{CCACHE_DIR}")
  53     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  54     # ccache does not accelerate link (ld), but let it handle it. by passing it
  55     # along with cc to python's distutils, we are able to workaround
  56     # https://bugs.python.org/issue8027.
  57     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  58   else(CCACHE_FOUND)
  59     message(FATAL_ERROR "Can't find ccache. Is it installed?")
  60   endif(CCACHE_FOUND)
  61 endif(WITH_CCACHE)
  62
  63 option(WITH_MANPAGE "Build man pages." ON)
  64 if(WITH_MANPAGE)
  65   find_program(SPHINX_BUILD
  66     sphinx-build)
  67   if(NOT SPHINX_BUILD)
  68     message(FATAL_ERROR "Can't find sphinx-build.")
  69   endif(NOT SPHINX_BUILD)
  70 endif(WITH_MANPAGE)
  71
  72 include_directories(
  73   ${PROJECT_BINARY_DIR}/src/include
  74   ${PROJECT_SOURCE_DIR}/src)
  75
  76 if(OFED_PREFIX)
  77   include_directories(${OFED_PREFIX}/include)
  78   link_directories(${OFED_PREFIX}/lib)
  79 endif()
  80
  81 if(FREEBSD)
  82   include_directories(/usr/local/include)
  83   link_directories(/usr/local/lib)
  84   list(APPEND CMAKE_REQUIRED_INCLUDES /usr/local/include)
  85 endif(FREEBSD)
  86
  87 #Check Includes
  88 include(CheckIncludeFiles)
  89 include(CheckIncludeFileCXX)
  90 include(CheckFunctionExists)
  91
  92 #put all the libs and binaries in one place
  93 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  94 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  95 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  96
  97
  98 CHECK_FUNCTION_EXISTS(fallocate CEPH_HAVE_FALLOCATE)
  99 CHECK_FUNCTION_EXISTS(posix_fadvise HAVE_POSIX_FADVISE)
 100 CHECK_FUNCTION_EXISTS(posix_fallocate HAVE_POSIX_FALLOCATE)
 101 CHECK_FUNCTION_EXISTS(syncfs HAVE_SYS_SYNCFS)
 102 CHECK_FUNCTION_EXISTS(sync_file_range HAVE_SYNC_FILE_RANGE)
 103 CHECK_FUNCTION_EXISTS(pwritev HAVE_PWRITEV)
 104 CHECK_FUNCTION_EXISTS(splice CEPH_HAVE_SPLICE)
 105 CHECK_FUNCTION_EXISTS(getgrouplist HAVE_GETGROUPLIST)
 106 CHECK_FUNCTION_EXISTS(fdatasync HAVE_FDATASYNC)
 107 CHECK_FUNCTION_EXISTS(strerror_r HAVE_STRERROR_R)
 108 CHECK_FUNCTION_EXISTS(name_to_handle_at HAVE_NAME_TO_HANDLE_AT)
 109 CHECK_FUNCTION_EXISTS(pipe2 HAVE_PIPE2)
 110 set(CMAKE_REQUIRED_LIBRARIES pthread)
 111 CHECK_FUNCTION_EXISTS(pthread_spin_init HAVE_PTHREAD_SPINLOCK)
 112 CHECK_FUNCTION_EXISTS(pthread_set_name_np HAVE_PTHREAD_SET_NAME_NP)
 113 CHECK_FUNCTION_EXISTS(pthread_setname_np HAVE_PTHREAD_SETNAME_NP)
 114 CHECK_FUNCTION_EXISTS(pthread_getname_np HAVE_PTHREAD_GETNAME_NP)
 115 CHECK_FUNCTION_EXISTS(pthread_rwlockattr_setkind_np HAVE_PTHREAD_RWLOCKATTR_SETKIND_NP)
 116 CHECK_FUNCTION_EXISTS(eventfd HAVE_EVENTFD)
 117 CHECK_FUNCTION_EXISTS(getprogname HAVE_GETPROGNAME)
 118
 119 CHECK_INCLUDE_FILES("linux/types.h" HAVE_LINUX_TYPES_H)
 120 CHECK_INCLUDE_FILES("linux/version.h" HAVE_LINUX_VERSION_H)
 121 CHECK_INCLUDE_FILES("arpa/nameser_compat.h" HAVE_ARPA_NAMESER_COMPAT_H)
 122 CHECK_INCLUDE_FILES("sys/mount.h" HAVE_SYS_MOUNT_H)
 123 CHECK_INCLUDE_FILES("sys/param.h" HAVE_SYS_PARAM_H)
 124 CHECK_INCLUDE_FILES("sys/types.h" HAVE_SYS_TYPES_H)
 125 CHECK_INCLUDE_FILES("sys/vfs.h" HAVE_SYS_VFS_H)
 126 CHECK_INCLUDE_FILES("sys/prctl.h" HAVE_SYS_PRCTL_H)
 127 CHECK_INCLUDE_FILES("execinfo.h" HAVE_EXECINFO_H)
 128 if(LINUX)
 129   CHECK_INCLUDE_FILES("sched.h" HAVE_SCHED)
 130 endif(LINUX)
 131 CHECK_INCLUDE_FILES("valgrind/helgrind.h" HAVE_VALGRIND_HELGRIND_H)
 132
 133 include(CheckTypeSize)
 134 set(CMAKE_EXTRA_INCLUDE_FILES "linux/types.h")
 135 CHECK_TYPE_SIZE(__be16 __BE16)
 136 CHECK_TYPE_SIZE(__be32 __BE32)
 137 CHECK_TYPE_SIZE(__be64 __BE64)
 138 CHECK_TYPE_SIZE(__le16 __LE16)
 139 CHECK_TYPE_SIZE(__le32 __LE32)
 140 CHECK_TYPE_SIZE(__le64 __LE64)
 141 CHECK_TYPE_SIZE(__u8 __U8)
 142 CHECK_TYPE_SIZE(__u16 __U16)
 143 CHECK_TYPE_SIZE(__u32 __U32)
 144 CHECK_TYPE_SIZE(__u64 __U64)
 145 CHECK_TYPE_SIZE(__s8 __S8)
 146 CHECK_TYPE_SIZE(__s16 __S16)
 147 CHECK_TYPE_SIZE(__s32 __S32)
 148 CHECK_TYPE_SIZE(__s64 __S64)
 149 unset(CMAKE_EXTRA_INCLUDE_FILES)
 150
 151 include(CheckSymbolExists)
 152 CHECK_SYMBOL_EXISTS(res_nquery "resolv.h" HAVE_RES_NQUERY)
 153 CHECK_SYMBOL_EXISTS(F_SETPIPE_SZ "linux/fcntl.h" CEPH_HAVE_SETPIPE_SZ)
 154 CHECK_SYMBOL_EXISTS(__func__ "" HAVE_FUNC)
 155 CHECK_SYMBOL_EXISTS(__PRETTY_FUNCTION__ "" HAVE_PRETTY_FUNC)
 156
 157 include(CheckCXXSourceCompiles)
 158 CHECK_CXX_SOURCE_COMPILES("
 159   #include <string.h>
 160   int main() { char x = *strerror_r(0, &x, sizeof(x)); return 0; }
 161   " STRERROR_R_CHAR_P)
 162
 163 include(CheckStructHasMember)
 164 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtim.tv_nsec sys/stat.h
 165   HAVE_STAT_ST_MTIM_TV_NSEC LANGUAGE C)
 166 CHECK_STRUCT_HAS_MEMBER("struct stat" st_mtimespec.tv_nsec sys/stat.h
 167   HAVE_STAT_ST_MTIMESPEC_TV_NSEC LANGUAGE C)
 168
 169 set(CEPH_MAN_DIR "share/man" CACHE STRING "Install location for man pages (relative to prefix).")
 170
 171 option(ENABLE_SHARED "build shared libraries" ON)
 172 if(ENABLE_SHARED)
 173   set(CEPH_SHARED SHARED)
 174 else(ENABLE_SHARED)
 175   set(CEPH_SHARED STATIC)
 176 endif(ENABLE_SHARED)
 177 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_SHARED})
 178
 179 option(WITH_RDMA "Enable RDMA in async messenger" ON)
 180 if(WITH_RDMA)
 181   find_package(rdma REQUIRED)
 182   set(HAVE_RDMA ${RDMA_FOUND})
 183 endif(WITH_RDMA)
 184
 185 find_package(Backtrace)
 186
 187 if(LINUX)
 188   find_package(udev REQUIRED)
 189   set(HAVE_UDEV ${UDEV_FOUND})
 190
 191   find_package(aio REQUIRED)
 192   set(HAVE_LIBAIO ${AIO_FOUND})
 193
 194   find_package(blkid REQUIRED)
 195   set(HAVE_BLKID ${BLKID_FOUND})
 196 else()
 197   set(HAVE_UDEV OFF)
 198   message(STATUS "Not using udev")
 199   set(HAVE_LIBAIO OFF)
 200   message(STATUS "Not using AIO")
 201   set(HAVE_BLKID OFF)
 202   message(STATUS "Not using BLKID")
 203 endif(LINUX)
 204
 205 option(WITH_OPENLDAP "OPENLDAP is here" ON)
 206 if(${WITH_OPENLDAP})
 207 find_package(OpenLdap REQUIRED)
 208 set(HAVE_OPENLDAP ${OPENLDAP_FOUND})
 209 endif(${WITH_OPENLDAP})
 210
 211 option(WITH_FUSE "Fuse is here" ON)
 212 if(${WITH_FUSE})
 213 find_package(fuse)
 214 set(HAVE_LIBFUSE ${FUSE_FOUND})
 215 endif(${WITH_FUSE})
 216
 217 option(WITH_XFS "XFS is here" ON)
 218 if(WITH_XFS)
 219   find_package(xfs)
 220   set(HAVE_LIBXFS ${XFS_FOUND})
 221 endif()
 222
 223 option(WITH_ZFS "enable LibZFS if found" OFF)
 224 if(WITH_ZFS)
 225   find_package(zfs)
 226   set(HAVE_LIBZFS ${ZFS_FOUND})
 227 endif()
 228
 229 option(WITH_SPDK "Enable SPDK" OFF)
 230 if(WITH_SPDK)
 231   find_package(dpdk REQUIRED)
 232   set(HAVE_SPDK TRUE)
 233 endif(WITH_SPDK)
 234
 235 option(WITH_PMEM "Enable PMEM" OFF)
 236 if(WITH_PMEM)
 237   find_package(pmem REQUIRED)
 238   set(HAVE_PMEM ${PMEM_FOUND})
 239 endif(WITH_PMEM)
 240
 241 # needs mds and? XXX
 242 option(WITH_LIBCEPHFS "libcephfs client library" ON)
 243
 244 # key-value store
 245 option(WITH_KVS "Key value store is here" ON)
 246
 247 # remote block storage
 248 option(WITH_RBD "Remote block storage is here" ON)
 249
 250 # KERNEL remote block storage
 251 option(WITH_KRBD "Kernel Remote block storage is here" ON)
 252
 253 if(WITH_KRBD AND WITHOUT_RBD)
 254   message(FATAL_ERROR "Cannot have WITH_KRBD with WITH_RBD.")
 255 endif()
 256
 257 option(WITH_LEVELDB "LevelDB is here" ON)
 258 if(WITH_LEVELDB)
 259   if(LEVELDB_PREFIX)
 260     include_directories(${LEVELDB_PREFIX}/include)
 261     link_directories(${LEVELDB_PREFIX}/lib)
 262   endif()
 263   find_package(leveldb REQUIRED)
 264   find_file(HAVE_LEVELDB_FILTER_POLICY leveldb/filter_policy.h PATHS ${LEVELDB_INCLUDE_DIR})
 265 endif(WITH_LEVELDB)
 266
 267 find_package(snappy REQUIRED)
 268
 269 option(WITH_LZ4 "LZ4 compression support" OFF)
 270 if(WITH_LZ4)
 271   find_package(LZ4 1.7 REQUIRED)
 272   set(HAVE_LZ4 ${LZ4_FOUND})
 273 endif(WITH_LZ4)
 274
 275 #if allocator is set on command line make sure it matches below strings
 276 if(ALLOCATOR)
 277   if(${ALLOCATOR} MATCHES "tcmalloc(_minimal)?")
 278     find_package(gperftools REQUIRED)
 279     set(HAVE_LIBTCMALLOC ON)
 280   elseif(${ALLOCATOR} STREQUAL "jemalloc")
 281     find_package(JeMalloc REQUIRED)
 282     set(HAVE_LIBJEMALLOC ${JEMALLOC_FOUND})
 283     set(HAVE_JEMALLOC 1)
 284   endif()
 285 else(ALLOCATOR)
 286   find_package(gperftools)
 287   set(HAVE_LIBTCMALLOC ${GPERFTOOLS_FOUND})
 288   if(NOT GPERFTOOLS_FOUND)
 289     find_package(JeMalloc)
 290     set(HAVE_LIBJEMALLOC ${JEMALLOC_FOUND})
 291   endif(NOT GPERFTOOLS_FOUND)
 292   if(GPERFTOOLS_FOUND)
 293     set(ALLOCATOR tcmalloc)
 294   elseif(JEMALLOC_FOUND)
 295     set(ALLOCATOR jemalloc)
 296   else()
 297     if(NOT FREEBSD)
 298       # FreeBSD already has jemalloc as its default allocator
 299       message(WARNING "tcmalloc and jemalloc not found, falling back to libc")
 300     endif()
 301     set(ALLOCATOR "libc")
 302   endif(GPERFTOOLS_FOUND)
 303 endif(ALLOCATOR)
 304
 305
 306 if(WITH_LIBCEPHFS OR WITH_KRBD)
 307   find_package(keyutils REQUIRED)
 308 endif()
 309
 310 find_package(CURL REQUIRED)
 311 set(CMAKE_REQUIRED_INCLUDES ${CURL_INCLUDE_DIRS})
 312 set(CMAKE_REQUIRED_LIBRARIES ${CURL_LIBRARIES})
 313 CHECK_SYMBOL_EXISTS(curl_multi_wait curl/curl.h HAVE_CURL_MULTI_WAIT)
 314
 315 # nss or cryptopp?
 316 option(WITH_NSS "Use NSS crypto and SSL implementations" ON)
 317 if (${WITH_NSS})
 318   find_package(NSS REQUIRED)
 319     set(USE_NSS 1)
 320     find_package(NSPR REQUIRED)
 321     set(CRYPTO_LIBS ${NSS_LIBRARIES} ${NSPR_LIBRARIES})
 322 else ()
 323   find_package(cryptopp REQUIRED)
 324     set(CRYPTO_LIBS ${CRYPTOPP_LIBRARIES})
 325     set(USE_CRYPTOPP 1)
 326 endif (${WITH_NSS})
 327
 328 option(WITH_SSL "SSL build selected" ON)
 329 if(USE_NSS)
 330   #nss
 331   set(SSL_LIBRARIES ${NSS_LIBRARIES})
 332   message(STATUS "SSL with NSS selected (Libs: ${SSL_LIBRARIES})")
 333 else(USE_NSS)
 334   #openssl
 335   find_package(OpenSSL REQUIRED)
 336   set(USE_OPENSSL ON)
 337   set(SSL_LIBRARIES ${OPENSSL_LIBRARIES})
 338   message(STATUS "SSL with OpenSSL selected (Libs: ${SSL_LIBRARIES})")
 339 endif(USE_NSS)
 340
 341 option(WITH_XIO "Enable XIO messaging" OFF)
 342 if(WITH_XIO)
 343   find_package(xio REQUIRED)
 344 set(HAVE_XIO ${XIO_FOUND})
 345 endif(WITH_XIO)
 346
 347 option(WITH_DPDK "Enable DPDK messaging" OFF)
 348 if(WITH_DPDK)
 349 find_package(dpdk)
 350 set(HAVE_DPDK ${DPDK_FOUND})
 351 endif(WITH_DPDK)
 352
 353 option(WITH_BLKIN "Use blkin to emit LTTng tracepoints for Zipkin" OFF)
 354 if(WITH_BLKIN)
 355   set(BLKIN_LIBRARIES blkin lttng-ust)
 356   include_directories(src/blkin/blkin-lib)
 357 endif(WITH_BLKIN)
 358
 359 option(WITH_BOOST_CONTEXT "Enable boost::asio stackful coroutines" ON)
 360 if(WITH_BOOST_CONTEXT)
 361   set(HAVE_BOOST_CONTEXT ON)
 362 endif()
 363
 364 #option for RGW
 365 option(WITH_RADOSGW "Rados Gateway is enabled" ON)
 366 option(WITH_RADOSGW_FCGI_FRONTEND "Rados Gateway's FCGI frontend is enabled" OFF)
 367 option(WITH_RADOSGW_BEAST_FRONTEND "Rados Gateway's Beast frontend is enabled" ON)
 368 if(WITH_RADOSGW)
 369   find_package(EXPAT REQUIRED)
 370   if(WITH_RADOSGW_FCGI_FRONTEND)
 371     find_package(fcgi REQUIRED)
 372   endif()
 373   if(WITH_RADOSGW_BEAST_FRONTEND AND NOT WITH_BOOST_CONTEXT)
 374     message(WARNING "disabling WITH_RADOSGW_BEAST_FRONTEND, which depends on WITH_BOOST_CONTEXT")
 375     set(WITH_RADOSGW_BEAST_FRONTEND OFF)
 376   endif()
 377 endif(WITH_RADOSGW)
 378
 379
 380 if (WITH_RADOSGW)
 381   if (NOT DEFINED OPENSSL_FOUND)
 382     message(STATUS "Looking for openssl anyways, because radosgw selected")
 383     find_package(OpenSSL)
 384   endif()
 385 # https://curl.haxx.se/docs/install.html mentions the
 386 # configure flags for various ssl backends
 387   execute_process(
 388     COMMAND
 389   "sh" "-c"
 390   "curl-config --configure | grep with-ssl"
 391   RESULT_VARIABLE NO_CURL_SSL_LINK
 392   ERROR_VARIABLE CURL_CONFIG_ERRORS
 393   )
 394   if (CURL_CONFIG_ERRORS)
 395     message(WARNING "unable to run curl-config; rgw cannot make ssl requests to external systems reliably")
 396   endif()
 397   find_package(OpenSSL)
 398   if (OPENSSL_FOUND)
 399     if (NOT NO_CURL_SSL_LINK)
 400       message(STATUS "libcurl is linked with openssl: explicitly setting locks")
 401       set(WITH_CURL_OPENSSL ON)
 402     endif() # CURL_SSL_LINK
 403     execute_process(
 404       COMMAND
 405         "sh" "-c"
 406         "objdump -p ${OPENSSL_SSL_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 407       OUTPUT_VARIABLE LIBSSL_SONAME
 408       ERROR_VARIABLE OBJDUMP_ERRORS
 409       RESULT_VARIABLE OBJDUMP_RESULTS
 410       OUTPUT_STRIP_TRAILING_WHITESPACE)
 411     if (OBJDUMP_RESULTS)
 412       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 413     endif()
 414     if (NOT OBJDUMP_ERRORS STREQUAL "")
 415       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 416     endif()
 417     execute_process(
 418       COMMAND
 419         "sh" "-c"
 420         "objdump -p ${OPENSSL_CRYPTO_LIBRARY} | sed -n 's/^  SONAME  *//p'"
 421       OUTPUT_VARIABLE LIBCRYPTO_SONAME
 422       ERROR_VARIABLE OBJDUMP_ERRORS
 423       RESULT_VARIABLE OBJDUMP_RESULTS
 424       OUTPUT_STRIP_TRAILING_WHITESPACE)
 425     if (OBJDUMP_RESULTS)
 426       message(FATAL_ERROR "can't run objdump: ${OBJDUMP_RESULTS}")
 427     endif()
 428     if (NOT OBJDUMP_ERRORS STREQUAL "")
 429       message(WARNING "message from objdump: ${OBJDUMP_ERRORS}")
 430     endif()
 431     message(STATUS "ssl soname: ${LIBSSL_SONAME}")
 432     message(STATUS "crypto soname: ${LIBCRYPTO_SONAME}")
 433   else()
 434     message(WARNING "ssl not found: rgw civetweb may fail to dlopen libssl libcrypto")
 435   endif()  # OPENSSL_FOUND
 436 endif (WITH_RADOSGW)
 437
 438 #option for CephFS
 439 option(WITH_CEPHFS "CephFS is enabled" ON)
 440
 441 #option for Mgr
 442 option(WITH_MGR "ceph-mgr is enabled" ON)
 443 if(WITH_MGR)
 444     set(Python_ADDITIONAL_VERSIONS 2.7)
 445     find_package(PythonInterp 2.7 REQUIRED)
 446     find_package(PythonLibs 2.7 REQUIRED)
 447     # Boost dependency check deferred to Boost section
 448 endif(WITH_MGR)
 449
 450 option(WITH_THREAD_SAFE_RES_QUERY "res_query is thread safe" OFF)
 451 if(WITH_THREAD_SAFE_RES_QUERY)
 452     set(HAVE_THREAD_SAFE_RES_QUERY 1 CACHE INTERNAL "Thread safe res_query supported.")
 453 endif(WITH_THREAD_SAFE_RES_QUERY)
 454
 455 option(WITH_REENTRANT_STRSIGNAL "strsignal is reentrant" OFF)
 456 if(WITH_REENTRANT_STRSIGNAL)
 457     set(HAVE_REENTRANT_STRSIGNAL 1 CACHE INTERNAL "Reentrant strsignal is supported.")
 458 endif(WITH_REENTRANT_STRSIGNAL)
 459
 460 set(HAVE_LIBROCKSDB 1)
 461
 462 # -lz link into kv
 463 find_package(ZLIB REQUIRED)
 464
 465 #option for EventTrace
 466 option(WITH_EVENTTRACE "Event tracing support" OFF)
 467
 468 #option for LTTng
 469 option(WITH_LTTNG "LTTng tracing is enabled" ON)
 470 if(${WITH_LTTNG})
 471   find_package(LTTngUST REQUIRED)
 472   find_program(LTTNG_GEN_TP
 473     lttng-gen-tp)
 474   if(NOT LTTNG_GEN_TP)
 475     message(FATAL_ERROR "Can't find lttng-gen-tp.")
 476   endif()
 477 endif(${WITH_LTTNG})
 478
 479 option(WITH_OSD_INSTRUMENT_FUNCTIONS OFF)
 480
 481 #option for Babeltrace
 482 option(WITH_BABELTRACE "Babeltrace libraries are enabled" ON)
 483 if(WITH_BABELTRACE)
 484   set(HAVE_BABELTRACE ON)
 485   find_package(babeltrace REQUIRED)
 486   set(HAVE_BABELTRACE_BABELTRACE_H ${BABELTRACE_FOUND})
 487   set(HAVE_BABELTRACE_CTF_EVENTS_H ${BABELTRACE_FOUND})
 488   set(HAVE_BABELTRACE_CTF_ITERATOR_H ${BABELTRACE_FOUND})
 489 endif(WITH_BABELTRACE)
 490
 491 option(DEBUG_GATHER "C_Gather debugging is enabled" ON)
 492 option(ENABLE_COVERAGE "Coverage is enabled" OFF)
 493 option(PG_DEBUG_REFS "PG Ref debugging is enabled" OFF)
 494
 495 option(WITH_TESTS "enable the build of ceph-test package scripts/binaries" ON)
 496
 497 option(WITH_FIO "Support for fio engines" OFF)
 498 if(WITH_FIO)
 499   find_package(fio REQUIRED)
 500 endif(WITH_FIO)
 501
 502 if(LINUX)
 503   add_definitions(-D__linux__)
 504 endif(LINUX)
 505
 506 # ASAN and friends
 507 option(WITH_ASAN "build with ASAN" OFF)
 508 option(WITH_ASAN_LEAK "explicitly enable ASAN leak detection" OFF)
 509
 510 if(WITH_ASAN)
 511   set(ASAN_CFLAGS "-fsanitize=address -fno-omit-frame-pointer")
 512   if(WITH_ASAN_LEAK)
 513     set(ASAN_CFLAGS "${ASAN_CFLAGS} -fsanitize=leak")
 514   endif()
 515   set(ASAN_LFLAGS "${CMAKE_EXE_LINKER_FLAGS} ${ASAN_CFLAGS} -lasan")
 516   set(CMAKE_EXE_LINKER_FLAGS "${ASAN_LFLAGS}")
 517   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ASAN_CFLAGS}")
 518   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${ASAN_CFLAGS}")
 519   if(HAVE_JEMALLOC)
 520     message(FATAL "ASAN does not work well with JeMalloc")
 521   endif()
 522 endif()
 523
 524 option(WITH_TSAN "build with TSAN" OFF)
 525 if(WITH_TSAN)
 526   if (WITH_ASAN AND WITH_ASAN_LEAK)
 527     message(FATAL_ERROR "Cannot combine -fsanitize-leak w/-fsanitize-thread")
 528   endif()
 529   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -pie -ltsan ")
 530   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -fPIC")
 531   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -fPIC")
 532   if(HAVE_JEMALLOC)
 533     message(FATAL "TSAN does not work well with JeMalloc")
 534   endif()
 535 endif()
 536
 537 option(WITH_UBSAN "build with UBSAN" OFF)
 538 if(WITH_UBSAN)
 539   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=undefined")
 540   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined")
 541   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=undefined")
 542   if(HAVE_JEMALLOC)
 543     message(FATAL "UBSAN does not work well with JeMalloc")
 544   endif()
 545 endif()
 546
 547 # Rocksdb
 548 option(WITH_SYSTEM_ROCKSDB "require and build with system rocksdb" OFF)
 549 if (WITH_SYSTEM_ROCKSDB)
 550   find_package(rocksdb REQUIRED)
 551 endif()
 552
 553 # Boost
 554 option(WITH_SYSTEM_BOOST "require and build with system Boost" OFF)
 555
 556 # Boost::thread depends on Boost::atomic, so list it explicitly.
 557 set(BOOST_COMPONENTS
 558   atomic thread system regex random program_options date_time iostreams
 559   filesystem)
 560 set(BOOST_HEADER_COMPONENTS container)
 561
 562 if(WITH_MGR)
 563         list(APPEND BOOST_COMPONENTS python)
 564 endif()
 565 if(WITH_BOOST_CONTEXT)
 566   list(APPEND BOOST_COMPONENTS context coroutine)
 567 endif()
 568
 569 set(Boost_USE_MULTITHREADED ON)
 570 # require minimally the bundled version
 571 if(WITH_SYSTEM_BOOST)
 572   if(ENABLE_SHARED)
 573     set(Boost_USE_STATIC_LIBS OFF)
 574   else()
 575     set(Boost_USE_STATIC_LIBS ON)
 576   endif()
 577   find_package(Boost 1.66 COMPONENTS ${BOOST_COMPONENTS} REQUIRED)
 578 else()
 579   set(BOOST_J 1 CACHE STRING
 580     "max jobs for Boost build") # override w/-DBOOST_J=<n>
 581   set(Boost_USE_STATIC_LIBS ON)
 582   include(BuildBoost)
 583   build_boost(1.66
 584     COMPONENTS ${BOOST_COMPONENTS} ${BOOST_HEADER_COMPONENTS})
 585   include_directories(BEFORE SYSTEM ${Boost_INCLUDE_DIRS})
 586 endif()
 587 set(Boost_USE_MULTITHREADED ON)
 588
 589 include_directories(SYSTEM ${PROJECT_BINARY_DIR}/include)
 590
 591 find_package(Threads REQUIRED)
 592
 593 option(WITH_SELINUX "build SELinux policy" OFF)
 594 if(WITH_SELINUX)
 595   find_file(SELINUX_MAKEFILE selinux/devel/Makefile
 596     PATH /usr/share)
 597   if(NOT SELINUX_MAKEFILE)
 598     message(FATAL_ERROR "Can't find selinux's Makefile")
 599   endif()
 600   add_subdirectory(selinux)
 601 endif(WITH_SELINUX)
 602
 603 # enables testing and creates Make check command
 604 add_custom_target(tests
 605   COMMENT "Building tests")
 606 enable_testing()
 607 set(CMAKE_CTEST_COMMAND ctest)
 608 add_custom_target(check
 609   COMMAND ${CMAKE_CTEST_COMMAND}
 610   DEPENDS tests)
 611
 612 add_subdirectory(src)
 613
 614 add_subdirectory(doc)
 615 if(WITH_MANPAGE)
 616   add_subdirectory(man)
 617 endif(WITH_MANPAGE)
 618
 619 option(WITH_SYSTEMD "install systemd target and service files" OFF)
 620 if(WITH_SYSTEMD)
 621   add_subdirectory(systemd)
 622 endif()
 623
 624 if(LINUX)
 625   add_subdirectory(etc/sysctl)
 626 endif()
 627
 628 include(CTags)
 629 option(CTAG_EXCLUDES "Exclude files/directories when running ctag.")
 630 add_tags(ctags
 631   SRC_DIR src
 632   TAG_FILE tags
 633   EXCLUDE_OPTS ${CTAG_EXCLUDES}
 634   EXCLUDES "*.js" "*.css")
 635 add_custom_target(tags DEPENDS ctags)